I frequently receive requests to automate the retrieval of user IDs for a list of arbitrary names, such as from Active Directory. The name list largely consists of last names followed by first names, but some of the names are reversed. Some of the names are nicknames or initials.

In our example case, the names in Active Directory aren’t properly normalized either. Merging AD Domains from multiple, older networks often results in non-normalized data (or more specifically, differently normalized data). Names may be entered as proper names or nicknames, and nicknames may be notated in ad-hoc formats (e.g., in parentheses, etc). Names may be initialed—especially middle names—and abbreviations may or may not have periods. Last names may have suffixes (Jr, III, etc.) in a variety of formats.

Because the names in AD are not normalized, plus the arbitrary state of the names list we have to match, there is no way that I know of for a script to reliably normalize the list or the database, let alone compare them both. We could attempt to build-in dictionaries of names and compare them, but we would still fail on corner cases.

For example, if I tell you a full name is some arrangement of ‘Ernie’, ‘Ford’, and ‘Tennessee’, how can you guarantee what order the partial names are? While you may be able to make an educated guess, how do you write a script that guesses correctly? What about ‘John Olivia Newton’? Even if you built a dictionary of English names, what if I gave you ‘Ali Muhammad’ with no specified order?

No matter how we attempt to automate matching these names to the data, there will still have to be a manual reckoning. The goal for the script is to make that manual process as simple and automatic as possible so that it can be done quickly, efficiently, and—most importantly—by somebody else. The goal isn’t to get 100% accuracy—80% would be nice with some lists. On the other hand, manually resolving 20% of a list of thousands of names is still a big job, but the 80% saving is huge.

If you have such a file, all you actually have to do is drop it onto this script, and the script will create an output file in the same folder. You can also pass the file name as a command-line parameter. The script doesn’t take extra parameters—the output file will be the input filename with ‘.out.tab’ tacked onto it, etc.

Name dumps typically mix up first and last names, so this script tries to match names in both directions. The exception to that is the simplest translation. If ‘Smith, Andrew’ is in the file, and matches to ‘Smith, Andrew’ in AD, there is a strong indication (the comma) that the names are in the same order. That’s considered a quick match and warrants no further resolution.

If the simple translation fails, the script begins to run queries against AD, successively truncating the names (attempting to remove anything like initials, suffixes, etc.), and using them as wildcards until something is found, and eventually trying pieces of the names if necessary. The output includes profile information, as available, to help identify users.

Caveats

• Quick matches run through a fast translation (the AD NameTranslate object built into XP). There is some room for error; if the names have duplicates, for example (note Gene Cox in the list below). If this assumption of accuracy doesn’t work for your situation, you can disable that function (set it to just return an empty string).
• There is no realistic way for a script to know that ‘Bob Smith’ could be listed as ‘Robert Smith’, so it keeps broadening the net until something becomes plausible. If there is already a ‘B. Smith’ of some other name, broader scans will not run, so Robert may never show in the list.
• Some queries (such as Bob Brown or Will Smith) may return too many names to be useful. There is a configurable threshold for that eventuality.

You will notice that the output file is a .tab (which is probably an unrecognized type on your system) and that it looks oddly formatted. The file is designed so that you can run through the output fairly rapidly in a text editor and delete extraneous names, leaving the correct user IDs. Open the remainder in Excel (just right-click the file, and open it with Excel, in most cases), and all of the user IDs are in the third column—so even though editing is a manual process, it’s still relatively quick and easy.

Attached is a sample of the output, with mostly trouble names included.

Wesley Walker	=	OurCorp\WWalker
Betn Gotham	=	OurCorp\BGotham
MacLarsen, William C. (Carlson) = ...
      {searching for 'MacLarsen' & 'William C. (Carlson)'}
      Carlson MacLarsen (Carlson MacLarsen Project Office) (MAC Services - Office) =	CMacLars
Ferrous, B D = ...
      {searching for 'Ferrous' & 'B D'}
      Ferrous, Brandon (Desktop Ops) =	BFerrou
      Ferrous, BD (Corporate Services) =	BDFerro
O'Malley, Katherine = ...
      {searching for 'O''Malley' & 'Katherine'}
      Katherine O'Malley (Company User Administration) (Company Administration) =	KOMalle
      Katherine O'Malley (Network & Server) =	KOMalle
Thistle, Bob = ...
      {searching for 'Thistle' & 'Bob'}
      did not find 'B* Thistle' or 'B* Bob'
      Broadening Search...
      {searching for 'Thistle'}
      Robert Thistle (Network & Server Group) =	RThistle
      Thistle, Alex (Michael Robert) =	AThistle
      {searching for 'Bob'}
      did not find '* Bob'
White, Clarence = ...
      {searching for 'White' & 'Clarence'}
      Found 57 of 'C* White' or 'B* Clarence'. 30 is too many.
Garofolo, Gerald = ...
      {searching for 'Garofolo' & 'Gerald'}
      Jerry Garofolo (Project Coordinator) (Business Support) =	JGarofol
Gene Cox      =     DOMAIN\ADMIN
Priestley Jr, Carl = ...
      {searching for 'Priestley Jr' & 'Carl'}
      did not find 'C* Priestley Jr' or 'C* Carl'
      Broadening Search...
      {searching for 'Priestley Jr'}
      did not find '* Priestley Jr'
      Trying just the first part (Priestley)
      {searching for 'Priestley*'}
      Nick Priestley =	NPriestle
      Priestley, Carl (Legacy Support)  =	CPriestle
      {searching for 'Carl'}
      Kelly Carl (HR) =	KCarl
      John Carl (HR) =	JCarl

Below is the script:

Option Explicit

Const LDAPOU = "dc=domain,dc=Company,dc=NET"
Const TOOMANYCHOICES=30

Const ForReading = 1
Const ForWriting = 2

dim objArgs
Set objArgs = WScript.Arguments
If objArgs.count < 1 Then
	wscript.echo "Usage: userstocomputers.vbs input.csv"
	wscript.quit
End If

Dim strInputFileName, strOutputFileName

strInputFileName = objArgs(0)
strOutputFileName=strInputFileName & ".tab"

Dim objFSO, objInputFile, objOutputFile, szScratch, szScratch1
Set objFSO = CREATEOBJECT("Scripting.FileSystemObject")
Set objInputFile = objFSO.OpenTextFile(strInputFileName,ForReading,false)
Set objOutputFile = objFSO.OpenTextFile(strOutputFileName,ForWriting,true)

Dim strLineText, objSystemSet, objSystem
While not objInputFile.AtEndOfStream

	strLineText = split(Trim(objInputFile.Readline), ",")
	if ubound(strLineText) > 0 then
		strLineText(0)=trim(strLineText(0))
		strLineText(1)=trim(strLineText(1))
		szScratch= strLineText(1) & " " & strLineText(0)
		szScratch1=TranslateADName(4, 3, szScratch)
		if len(szScratch1) > 0 then
			objOutputFile.WriteLine szScratch & vbtab & "=" & vbtab & szScratch1
		else
			szScratch= strLineText(0) & ", " & strLineText(1)
			szScratch1=TranslateADName(4, 3, szScratch)
			if len(szScratch1) > 0 then
				objOutputFile.WriteLine szScratch & vbtab & "=" & vbtab & szScratch1
			else
				objOutputFile.WriteLine szScratch & " = ..."

				if LookupADName( strLineText(0), strLineText(1) )=0 then
					objOutputFile.WriteLine vbtab & "Broadening Search..."
					if LookupADName(strLineText(0), "")=0 then
						if instr(strLineText(0), " ")>0 then
							objOutputFile.WriteLine vbtab & "Trying just the first part (" & left(strLineText(0),instr(strLineText(0), " ")-1) & ")"
							LookupADName left(strLineText(0),instr(strLineText(0), " ")-1)&"*", ""
						end if
					end if
					if LookupADName(strLineText(1), "")=0 then
						if instr(strLineText(1), " ")>0 then
							objOutputFile.WriteLine vbtab & "Trying just the first part (" & left(strLineText(1),instr(strLineText(1), " ")-1) & ")"
							LookupADName left(strLineText(1),instr(strLineText(1), " ")-1)&"*", ""
						end if
					end if
				end if
			end if
		end if
	elseif ubound(strLineText) = 0 then
		strLineText(0)=trim(strLineText(0))
		szScratch1=strLineText(0)  & vbtab & "=" & vbtab & TranslateADName(4, 3, strLineText(0) )
			if len(szScratch1) > 0 then
				objOutputFile.WriteLine szScratch & vbtab & "=" & vbtab & szScratch1
			else
				objOutputFile.WriteLine szScratch & " = ..."
				LookupADName strLineText(0), ""
			end if
	end if
Wend
Wscript.Echo "Done"

Function TranslateADName(FromType, ToType, FromName)
	Dim objTranslator
	Const ADS_NAME_INITTYPE_GC					= 3

	Const   ADS_NAME_TYPE_1779					= 1
	Const   ADS_NAME_TYPE_CANONICAL				= 2
	Const   ADS_NAME_TYPE_NT4					= 3
	Const   ADS_NAME_TYPE_DISPLAY					= 4
	Const   ADS_NAME_TYPE_DOMAIN_SIMPLE			= 5
	Const   ADS_NAME_TYPE_ENTERPRISE_SIMPLE			= 6
	Const   ADS_NAME_TYPE_GUID					= 7
	Const   ADS_NAME_TYPE_UNKNOWN				= 8
	Const   ADS_NAME_TYPE_USER_PRINCIPAL_NAME		= 9
	Const   ADS_NAME_TYPE_CANONICAL_EX				= 10
	Const   ADS_NAME_TYPE_SERVICE_PRINCIPAL_NAME		= 11
	Const   ADS_NAME_TYPE_SID_OR_SID_HISTORY_NAME	= 12 

	Set objTranslator = CreateObject("NameTranslate")

	on error resume next
	objTranslator.Init ADS_NAME_INITTYPE_GC, ""
	objTranslator.Set FromType, FromName

	TranslateADName = objTranslator.Get(ToType)
	on error goto 0
End Function

Function LookupADName(fname, lname) ' Returns number of records
	dim objConnection, objCommand, objRecordSet, searchscope, strItem
	On Error Resume Next
	Const ADS_SCOPE_SUBTREE = 2

	fname=trim(replace(fname, "'", "''"))
	lname=trim(replace(lname, "'", "''"))
	if len(fname)=0 and len(lname)=0 then exit function

	Set objConnection = CreateObject("ADODB.Connection")
	Set objCommand =   CreateObject("ADODB.Command")
	objConnection.Provider = "ADsDSOObject"
	objConnection.Open "Active Directory Provider"
	Set objCommand.ActiveConnection = objConnection

	objCommand.Properties("Page Size") = 1000
	objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE
	if len(fname)=0 or len(lname)=0 then
		lname = fname & lname
		if lname = "*" then
			objOutputFile.WriteLine vbtab & "Skipping '*'"
			exit function
		end if
		objOutputFile.WriteLine vbtab & "{searching for '" & lname & "'}"
		objCommand.CommandText = "SELECT sAMAccountName, displayName, department, description FROM 'LDAP://" & LDAPOU & "' WHERE objectCategory='user' AND " & _
			"sn='" & lname & "'"
		searchscope="'* " & lname & "'"
	else
		objOutputFile.WriteLine vbtab & "{searching for '" & fname & "' & '" & lname & "'}"
		objCommand.CommandText = "SELECT sAMAccountName, displayName, department, description FROM 'LDAP://" & LDAPOU & "' WHERE objectCategory='user' AND " & _
			"( (givenName='" & left(lname,1) & "*' AND sn='" & fname & "') OR " & _
			"(givenName='" & left(fname,1) & "*' AND sn='" & lname & "') )"
		searchscope="'" & left(lname,1) & "* " & fname & "' or '" & left(fname,1) & "* " & lname & "'"
	end if
	Set objRecordSet = objCommand.Execute
	objRecordSet.MoveFirst
	LookupADName = objRecordSet.RecordCount
	if objRecordSet.RecordCount>=TOOMANYCHOICES then
		objOutputFile.WriteLine vbtab & "Found " & objRecordSet.RecordCount & " of " & searchscope & ". " & TOOMANYCHOICES & " is too many."
	elseif objRecordSet.RecordCount=0 then
		objOutputFile.WriteLine vbtab & "did not find " & searchscope
	else
		Do Until objRecordSet.EOF
			objOutputFile.Write vbtab & objRecordSet.Fields("displayName").Value
			if not isnull(objRecordSet.Fields("description").Value) then
				For each strItem in objRecordSet.Fields("description").Value
					if len (strItem)>0 then objOutputFile.Write  " (" & strItem & ")"
				Next
			end if
			if len(objRecordSet.Fields("department").Value)>0 then objOutputFile.Write  " (" & objRecordSet.Fields("department").Value & ")"
			objOutputFile.WriteLine  " ="& vbtab & objRecordSet.Fields("sAMAccountName").Value
			objRecordSet.MoveNext
		Loop
	end if
	on error goto 0
End Function

1. We receive surveys/orders/documents that have been filled out by various people as Excel spreadsheets
2. We need to put the information into a database
3. We want you to write a script to automate the imports.

My thoughts as a scripter:

1. This is an excellent way to keep a contractor in a job for a long time.
2. You will never get everybody to input the data the same way into Excel. Nobody ever has.
   • People will put things on different lines, because it is Excel, and they can.
   • People will never enter data the same way. If you give them a yes/no column in a spreadsheet, some time you will get “yes/no”, sometimes “y/n”, “t,f”, “X, ”, “☑,☒”, “☺,☹”, “+,-”. Every time somebody creates a new item, the script breaks, and has to be modified to compensate, or you have to send the form back or correct it. With a web form, you just give them a yes/no box, or a check box, and they can’t put in different values (it’s self-correcting).
   • Whenever the user changes the values, if you haven’t predicted what they will enter, you will have to manually redo those files, because they will break the script. This always happens. Then you have to go back and fix the script.
3. If you want to run the script on a server, you either have to work out how to dissect XLS files, or install Excel on the server. The first is a royal pain, and the second shouldn’t be allowed to happen.

The best way to deal with this is to avoid it altogether:

1. Get your database in a SQL database back end (and don’t confuse Excel with a database.)
2. Set up a web form that looks like the spreadsheet, to do data input straight into the database
3. Set up list boxes, etc, so that the data is picked, and not created on the fly.
4. Instead of filling out the spreadsheet, users just fill out a web page.
5. If you really want, you can send out Access-via-Outlook forms to anybody with Outlook. They are like Access forms, except they get emailed, and they send the data straight into a database.

Miscellaneous advantages to web form:

1. It takes almost all of the work out
2. You don’t have to correct data for people. If there’s a problem, it can let them know as they enter it, and they can correct it on the spot.
3. You don’t have to worry about different versions of Excel and interoperability.
4. You don’t even have to worry if people have Excel.
5. People can fill in a web form from any machine–PC, Macintosh, Blackberry.
6. If you change things, the web form changes along with the back end, and anybody going to the form automatically gets the new version–with Excel, you get back what you sent out any time ago.

Doing this as a script will cost you a lot of time and effort (which probably translates into money), and will never work right (which will cost you a lot more money). Doing this as a web form will be relatively easy (and cheap), and the data will be self-correcting. If you want to do Access-via-Outlook forms, you will have plenty of money left over, in case you need to hire somebody to create that (it shouldn’t be hard, nor take long to make.) Besides, starting with a website, and just having an input form added to it is barely more work than the website by itself–and whoever builds the website will probably build the form as they build the site, anyway, just to do test data (I always do, when I build databases.)

If you still insist on doing this as a script, do it in Perl. Perl has modules to parse XLS files (so it doesn’t need Excel) and is built to parse native language text–which it will have to do for anything people can type in wrong–and can compile into an EXE, if you need to run it on a server without installing a new language. If you don’t need to run it on a server, Perl is still the best language to do it in. It’d still be an expensive and troublesome pain, but not as much as other scripting languages.

This kind of project is a knock-off for a web-developer. It’s a career for a scripter.